Rambling Developer

Recent Posts


Archives


Rambling Developer

Getting Selected Values of a Flex List of Checkboxes

adminadmin

This example will be a continuation of the post “Creating A Flex Spark List of Checkbox Bound To XML DataProvider”. If you have not read that tutorial and are not sure how to create a List of Checkboxes form XML, please see that tutorial first.

Now, we will need to do severals things to know the selected value of our list items:

Add a “selected” attribute for each person in our XML dataprovider
Update the checkbox in the itemrenderer so that it is selected only when the dataprovider’s “selected” attribute is “true”
Add a method to update the dataprovider for the itemrenderer
Add a method to setup an EventListener to be notified of changes to the dataprovider
Add a method to extract the current selected values from the dataprovider
So, first, we need to add the “selected” attribute to our dataprovider elements. That is done quite simply as you can see below:

<fx:xml id="namesXML" format="e4x">
  <people>
    <person name="Leon" selected="false">
    <person name="Mathilda" selected="false">
    <person name="Stansfield" selected="false">
    <person name="Benny" selected="false">
  </person></person></person></person></people>
</fx:xml>

Next, we need to update the definition of the checkbox so that it shows a checkmark only when the dataprovider’s “selected” attribute is true. We’ll also need to update the checkbox definition to call a method called onCheckboxChange when the checkbox sends a “change” event. We can see that definition here:

<s:checkbox id="checkBox" label="{data.@name}" change="onCheckboxChange(event)" selected="{data.@selected=='true'}">
</s:checkbox>

In order for that selected attibute to update in the dataprovider when the user clicks it we need to add the onCheckboxChange method seen in the definition above. This method will set the “selected” attribute to true when the checkbox is checked and false when the checkbox is not checked. Simple, right? You can see the method here:


protected function onCheckboxChange(changeEvent:Event):void{
  //When the checkbox changes update the data provider's "selected" attribute
  data.@selected = checkBox.selected ? "true" : "false";
}

Ok. Now we are almost there. Next, in our applicaton file, we need to create two methods. The first will be onCreationComplete, which will fire when the application has been created (note: this method is triggered by the application definition with the code creationComplete=”onCreationComplete()”). This method will populate a variable called “personDataProvider” which is the dataProvider to our list. Then we will add an EventListener to the personDataProvider that listens to CollectionChange events so we know when a user is selected or unselected. The method is below:


protected function onCreationComplete():void{
  //Initialize the dataprovider
  personDataProvider = new XMLListCollection(namesXML.children());
  //Add a listener so we know when the dataprovider is updated
  personDataProvider.addEventListener(CollectionEvent.COLLECTION_CHANGE, onListChange);
}

Finally, we simply need to create the final method which is called every time the personDataProvider is updated. This method simply loops over all of the person elements in our list, finds which people are selected, and then adds their names to a text element. See the code here:


protected function onListChange(changeEvent:Event):void{
  //Clear the selected person text since we'll be building it here
  selectedPersonText.text = "Selected People:";
  for each (var personXML:XML in personDataProvider) {
    //Add all selected person names to our text component
    if(personXML.@selected=="true"){
      //Add the person's name to the text component
      selectedPersonText.text += " " + personXML.@name
    }
  }
}

That’s it! We now have a way of finding out which people are selected in our checkbox list. See the example below (you can see the source code by right clicking on the example application):

Comments 0
There are currently no comments.